X-Git-Url: http://git.rohieb.name/openwrt.git/blobdiff_plain/47267182d5a91cb9c58270bfb1e97376fd5f07eb..b73050fb3f1bfd0572b8e0738b3f441cc5da806b:/package/base-files/default/lib/config/template.awk

diff --git a/package/base-files/default/lib/config/template.awk b/package/base-files/default/lib/config/template.awk
new file mode 100644
index 000000000..9ce32b74f
--- /dev/null
+++ b/package/base-files/default/lib/config/template.awk
@@ -0,0 +1,42 @@
+# Copyright (C) 2006 OpenWrt.org
+
+{
+	line=$0
+	gsub(/^[ \t]*/, "")
+	gsub(/[ \t]*$/, "")
+}
+
+$1 == "@define" {
+	v[$2] = $3
+}
+
+$1 == "@ifdef" {
+	if_open = 1
+	if (v[$2] != "") noprint = 0
+	else noprint = 1
+}
+
+$1 == "@ifndef" {
+	if_open = 1
+	if (v[$2] != "") noprint = 1
+	else noprint = 0
+}
+
+$1 == "@else" {
+	if (noprint == 1) noprint = 0
+	else noprint = 1
+}
+
+($1 !~ /^@[a-zA-Z]/) && (noprint != 1) {
+	n=split(line "@@", a, /@@/)
+	for (i=1; i<=n; i++) {
+		if ((i % 2) == 1) printf a[i]
+		else printf v[a[i]]
+	}
+	print ""
+}
+
+$1 == "@endif" {
+	if_open = 0
+	noprint = 0
+}