<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/env perl
use FindBin;
use lib "$FindBin::Bin";
use strict;
use metadata;

my %board;

sub confstr($) {
	my $conf = shift;
	$conf =~ tr#/\.\-/#___#;
	return $conf;
}

sub parse_target_metadata() {
	my $file = shift @ARGV;
	my ($target, @target, $profile);
	my %target;

	open FILE, "&lt;$file" or do {
		warn "Can't open file '$file': $!\n";
		return;
	};
	while (&lt;FILE&gt;) {
		chomp;
		/^Target:\s*(.+)\s*$/ and do {
			my $name = $1;
			$target = {
				id =&gt; $name,
				board =&gt; $name,
				boardconf =&gt; confstr($name),
				conf =&gt; confstr($name),
				profiles =&gt; [],
				features =&gt; [],
				depends =&gt; [],
				subtargets =&gt; []
			};
			push @target, $target;
			$target{$name} = $target;
			if ($name =~ /([^\/]+)\/([^\/]+)/) {
				push @{$target{$1}-&gt;{subtargets}}, $2;
				$target-&gt;{board} = $1;
				$target-&gt;{boardconf} = confstr($1);
				$target-&gt;{subtarget} = 1;
				$target-&gt;{parent} = $target{$1};
			}
		};
		/^Target-Name:\s*(.+)\s*$/ and $target-&gt;{name} = $1;
		/^Target-Path:\s*(.+)\s*$/ and $target-&gt;{path} = $1;
		/^Target-Arch:\s*(.+)\s*$/ and $target-&gt;{arch} = $1;
		/^Target-Arch-Packages:\s*(.+)\s*$/ and $target-&gt;{arch_packages} = $1;
		/^Target-Features:\s*(.+)\s*$/ and $target-&gt;{features} = [ split(/\s+/, $1) ];
		/^Target-Depends:\s*(.+)\s*$/ and $target-&gt;{depends} = [ split(/\s+/, $1) ];
		/^Target-Description:/ and $target-&gt;{desc} = get_multiline(*FILE);
		/^Target-Optimization:\s*(.+)\s*$/ and $target-&gt;{cflags} = $1;
		/^Linux-Version:\s*(.+)\s*$/ and $target-&gt;{version} = $1;
		/^Linux-Release:\s*(.+)\s*$/ and $target-&gt;{release} = $1;
		/^Linux-Kernel-Arch:\s*(.+)\s*$/ and $target-&gt;{karch} = $1;
		/^Default-Subtarget:\s*(.+)\s*$/ and $target-&gt;{def_subtarget} = $1;
		/^Default-Packages:\s*(.+)\s*$/ and $target-&gt;{packages} = [ split(/\s+/, $1) ];
		/^Target-Profile:\s*(.+)\s*$/ and do {
			$profile = {
				id =&gt; $1,
				name =&gt; $1,
				packages =&gt; []
			};
			push @{$target-&gt;{profiles}}, $profile;
		};
		/^Target-Profile-Name:\s*(.+)\s*$/ and $profile-&gt;{name} = $1;
		/^Target-Profile-Packages:\s*(.*)\s*$/ and $profile-&gt;{packages} = [ split(/\s+/, $1) ];
		/^Target-Profile-Description:\s*(.*)\s*/ and $profile-&gt;{desc} = get_multiline(*FILE);
		/^Target-Profile-Config:/ and $profile-&gt;{config} = get_multiline(*FILE, "\t");
		/^Target-Profile-Kconfig:/ and $profile-&gt;{kconfig} = 1;
	}
	close FILE;
	foreach my $target (@target) {
		next if @{$target-&gt;{subtargets}} &gt; 0;
		@{$target-&gt;{profiles}} &gt; 0 or $target-&gt;{profiles} = [
			{
				id =&gt; 'Default',
				name =&gt; 'Default',
				packages =&gt; []
			}
		];
	}
	return @target;
}

sub gen_kconfig_overrides() {
	my %config;
	my %kconfig;
	my $package;
	my $pkginfo = shift @ARGV;
	my $cfgfile = shift @ARGV;

	# parameter 2: build system config
	open FILE, "&lt;$cfgfile" or return;
	while (&lt;FILE&gt;) {
		/^(CONFIG_.+?)=(.+)$/ and $config{$1} = 1;
	}
	close FILE;

	# parameter 1: package metadata
	open FILE, "&lt;$pkginfo" or return;
	while (&lt;FILE&gt;) {
		/^Package:\s*(.+?)\s*$/ and $package = $1;
		/^Kernel-Config:\s*(.+?)\s*$/ and do {
			my @config = split /\s+/, $1;
			foreach my $config (@config) {
				my $val = 'm';
				my $override;
				if ($config =~ /^(.+?)=(.+)$/) {
					$config = $1;
					$override = 1;
					$val = $2;
				}
				if ($config{"CONFIG_PACKAGE_$package"} and ($config ne 'n')) {
					$kconfig{$config} = $val;
				} elsif (!$override) {
					$kconfig{$config} or $kconfig{$config} = 'n';
				}
			}
		};
	};
	close FILE;

	foreach my $kconfig (sort keys %kconfig) {
		if ($kconfig{$kconfig} eq 'n') {
			print "# $kconfig is not set\n";
		} else {
			print "$kconfig=$kconfig{$kconfig}\n";
		}
	}
}

sub merge_package_lists($$) {
	my $list1 = shift;
	my $list2 = shift;
	my @l = ();
	my %pkgs;

	foreach my $pkg (@$list1, @$list2) {
		$pkgs{$pkg} = 1;
	}
	foreach my $pkg (keys %pkgs) {
		push @l, $pkg unless ($pkg =~ /^-/ or $pkgs{"-$pkg"});
	}
	return sort(@l);
}

sub target_config_features(@) {
	my $ret;

	while ($_ = shift @_) {
		/broken/ and $ret .= "\tdepends BROKEN\n";
		/audio/ and $ret .= "\tselect AUDIO_SUPPORT\n";
		/display/ and $ret .= "\tselect DISPLAY_SUPPORT\n";
		/gpio/ and $ret .= "\tselect GPIO_SUPPORT\n";
		/pci/ and $ret .= "\tselect PCI_SUPPORT\n";
		/pcie/ and $ret .= "\tselect PCIE_SUPPORT\n";
		/usb/ and $ret .= "\tselect USB_SUPPORT\n";
		/usbgadget/ and $ret .= "\tselect USB_GADGET_SUPPORT\n";
		/pcmcia/ and $ret .= "\tselect PCMCIA_SUPPORT\n";
		/squashfs/ and $ret .= "\tselect USES_SQUASHFS\n";
		/jffs2/ and $ret .= "\tselect USES_JFFS2\n";
		/ext4/ and $ret .= "\tselect USES_EXT4\n";
		/targz/ and $ret .= "\tselect USES_TARGZ\n";
		/cpiogz/ and $ret .= "\tselect USES_CPIOGZ\n";
		/ubifs/ and $ret .= "\tselect USES_UBIFS\n";
		/fpu/ and $ret .= "\tselect HAS_FPU\n";
		/spe_fpu/ and $ret .= "\tselect HAS_SPE_FPU\n";
		/ramdisk/ and $ret .= "\tselect USES_INITRAMFS\n";
		/powerpc64/ and $ret .= "\tselect powerpc64\n";
		/nommu/ and $ret .= "\tselect NOMMU\n";
	}
	return $ret;
}

sub target_name($) {
	my $target = shift;
	my $parent = $target-&gt;{parent};
	if ($parent) {
		return $target-&gt;{parent}-&gt;{name}." - ".$target-&gt;{name};
	} else {
		return $target-&gt;{name};
	}
}

sub kver($) {
	my $v = shift;
	$v =~ tr/\./_/;
	if (substr($v,0,2) eq "2_") {
		$v =~ /(\d+_\d+_\d+)(_\d+)?/ and $v = $1;
	} else {
		$v =~ /(\d+_\d+)(_\d+)?/ and $v = $1;
	}
	return $v;
}

sub print_target($) {
	my $target = shift;
	my $features = target_config_features(@{$target-&gt;{features}});
	my $help = $target-&gt;{desc};
	my $confstr;

	chomp $features;
	$features .= "\n";
	if ($help =~ /\w+/) {
		$help =~ s/^\s*/\t  /mg;
		$help = "\thelp\n$help";
	} else {
		undef $help;
	}

	my $v = kver($target-&gt;{version});
	if (@{$target-&gt;{subtargets}} == 0) {
	$confstr = &lt;&lt;EOF;
config TARGET_$target-&gt;{conf}
	bool "$target-&gt;{name}"
	select LINUX_$v
EOF
	}
	else {
		$confstr = &lt;&lt;EOF;
config TARGET_$target-&gt;{conf}
	bool "$target-&gt;{name}"
EOF
	}
	if ($target-&gt;{subtarget}) {
		$confstr .= "\tdepends TARGET_$target-&gt;{boardconf}\n";
	}
	if (@{$target-&gt;{subtargets}} &gt; 0) {
		$confstr .= "\tselect HAS_SUBTARGETS\n";
	} else {
		$confstr .= $features;
	}

	if ($target-&gt;{arch} =~ /\w/) {
		$confstr .= "\tselect $target-&gt;{arch}\n";
	}
	foreach my $dep (@{$target-&gt;{depends}}) {
		my $mode = "depends";
		my $flags;
		my $name;

		$dep =~ /^([@\+\-]+)(.+)$/;
		$flags = $1;
		$name = $2;

		next if $name =~ /:/;
		$flags =~ /-/ and $mode = "deselect";
		$flags =~ /\+/ and $mode = "select";
		$flags =~ /@/ and $confstr .= "\t$mode $name\n";
	}
	$confstr .= "$help\n\n";
	print $confstr;
}

sub gen_target_config() {
	my @target = parse_target_metadata();
	my %defaults;

	my @target_sort = sort {
		target_name($a) cmp target_name($b);
	} @target;


	print &lt;&lt;EOF;
choice
	prompt "Target System"
	default TARGET_brcm47xx
	reset if !DEVEL
	
EOF

	foreach my $target (@target_sort) {
		next if $target-&gt;{subtarget};
		print_target($target);
	}

	print &lt;&lt;EOF;
endchoice

choice
	prompt "Subtarget" if HAS_SUBTARGETS
EOF
	foreach my $target (@target) {
		next unless $target-&gt;{def_subtarget};
		print &lt;&lt;EOF;
	default TARGET_$target-&gt;{conf}_$target-&gt;{def_subtarget} if TARGET_$target-&gt;{conf}
EOF
	}
	print &lt;&lt;EOF;

EOF
	foreach my $target (@target) {
		next unless $target-&gt;{subtarget};
		print_target($target);
	}

print &lt;&lt;EOF;
endchoice

choice
	prompt "Target Profile"

EOF

	foreach my $target (@target) {
		my $profiles = $target-&gt;{profiles};

		foreach my $profile (@$profiles) {
			print &lt;&lt;EOF;
config TARGET_$target-&gt;{conf}_$profile-&gt;{id}
	bool "$profile-&gt;{name}"
	depends TARGET_$target-&gt;{conf}
$profile-&gt;{config}
EOF
			$profile-&gt;{kconfig} and print "\tselect PROFILE_KCONFIG\n";
			my @pkglist = merge_package_lists($target-&gt;{packages}, $profile-&gt;{packages});
			foreach my $pkg (@pkglist) {
				print "\tselect DEFAULT_$pkg\n";
				$defaults{$pkg} = 1;
			}
			my $help = $profile-&gt;{desc};
			if ($help =~ /\w+/) {
				$help =~ s/^\s*/\t  /mg;
				$help = "\thelp\n$help";
			} else {
				undef $help;
			}
			print "$help\n";
		}
	}

	print &lt;&lt;EOF;
endchoice

config HAS_SUBTARGETS
	bool

config TARGET_BOARD
	string

EOF
	foreach my $target (@target) {
		$target-&gt;{subtarget} or	print "\t\tdefault \"".$target-&gt;{board}."\" if TARGET_".$target-&gt;{conf}."\n";
	}
	print &lt;&lt;EOF;
config TARGET_ARCH_PACKAGES
	string
	
EOF
	foreach my $target (@target) {
		next if @{$target-&gt;{subtargets}} &gt; 0;
		print "\t\tdefault \"".($target-&gt;{arch_packages} || $target-&gt;{board})."\" if TARGET_".$target-&gt;{conf}."\n";
	}
	print &lt;&lt;EOF;

config DEFAULT_TARGET_OPTIMIZATION
	string
EOF
	foreach my $target (@target) {
		next if @{$target-&gt;{subtargets}} &gt; 0;
		print "\tdefault \"".$target-&gt;{cflags}."\" if TARGET_".$target-&gt;{conf}."\n";
	}
	print "\tdefault \"-Os -pipe -funit-at-a-time\"\n";

	my %kver;
	foreach my $target (@target) {
		my $v = kver($target-&gt;{version});
		next if $kver{$v};
		$kver{$v} = 1;
		print &lt;&lt;EOF;

config LINUX_$v
	bool

EOF
	}
	foreach my $def (sort keys %defaults) {
		print "\tconfig DEFAULT_".$def."\n";
		print "\t\tbool\n\n";
	}
}

my %dep_check;
sub __find_package_dep($$) {
	my $pkg = shift;
	my $name = shift;
	my $deps = ($pkg-&gt;{vdepends} or $pkg-&gt;{depends});

	return 0 unless defined $deps;
	foreach my $dep (@{$deps}) {
		next if $dep_check{$dep};
		$dep_check{$dep} = 1;
		return 1 if $dep eq $name;
		return 1 if ($package{$dep} and (__find_package_dep($package{$dep},$name) == 1));
	}
	return 0;
}

# wrapper to avoid infinite recursion
sub find_package_dep($$) {
	my $pkg = shift;
	my $name = shift;

	%dep_check = ();
	return __find_package_dep($pkg, $name);
}

sub package_depends($$) {
	my $a = shift;
	my $b = shift;
	my $ret;

	return 0 if ($a-&gt;{submenu} ne $b-&gt;{submenu});
	if (find_package_dep($a, $b-&gt;{name}) == 1) {
		$ret = 1;
	} elsif (find_package_dep($b, $a-&gt;{name}) == 1) {
		$ret = -1;
	} else {
		return 0;
	}
	return $ret;
}

sub mconf_depends {
	my $pkgname = shift;
	my $depends = shift;
	my $only_dep = shift;
	my $res;
	my $dep = shift;
	my $seen = shift;
	my $parent_condition = shift;
	$dep or $dep = {};
	$seen or $seen = {};

	$depends or return;
	my @depends = @$depends;
	foreach my $depend (@depends) {
		my $m = "depends";
		my $flags = "";
		$depend =~ s/^([@\+]+)// and $flags = $1;
		my $vdep;
		my $condition = $parent_condition;

		next if $condition eq $depend;
		next if $seen-&gt;{"$parent_condition:$depend"};
		$seen-&gt;{"$parent_condition:$depend"} = 1;
		if ($depend =~ /^(.+):(.+)$/) {
			if ($1 ne "PACKAGE_$pkgname") {
				if ($condition) {
					$condition = "$condition &amp;&amp; $1";
				} else {
					$condition = $1;
				}
			}
			$depend = $2;
		}
		next if $package{$depend} and $package{$depend}-&gt;{buildonly};
		if ($vdep = $package{$depend}-&gt;{vdepends}) {
			$depend = join("||", map { "PACKAGE_".$_ } @$vdep);
		} else {
			$flags =~ /\+/ and do {
				# Menuconfig will not treat 'select FOO' as a real dependency
				# thus if FOO depends on other config options, these dependencies
				# will not be checked. To fix this, we simply emit all of FOO's
				# depends here as well.
				$package{$depend} and mconf_depends($pkgname, $package{$depend}-&gt;{depends}, 1, $dep, $seen, $condition);

				$m = "select";
				next if $only_dep;
			};
			$flags =~ /@/ or $depend = "PACKAGE_$depend";
			if ($condition) {
				if ($m =~ /select/) {
					$depend = "$depend if $condition";
				} else {
					$depend = "!($condition) || $depend";
				}
			}
		}
		$dep-&gt;{$depend} =~ /select/ or $dep-&gt;{$depend} = $m;
	}
	foreach my $depend (keys %$dep) {
		my $m = $dep-&gt;{$depend};
		$res .= "\t\t$m $depend\n";
	}
	return $res;
}

sub print_package_config_category($) {
	my $cat = shift;
	my %menus;
	my %menu_dep;

	return unless $category{$cat};

	print "menu \"$cat\"\n\n";
	my %spkg = %{$category{$cat}};

	foreach my $spkg (sort {uc($a) cmp uc($b)} keys %spkg) {
		foreach my $pkg (@{$spkg{$spkg}}) {
			next if $pkg-&gt;{buildonly};
			my $menu = $pkg-&gt;{submenu};
			if ($menu) {
				$menu_dep{$menu} or $menu_dep{$menu} = $pkg-&gt;{submenudep};
			} else {
				$menu = 'undef';
			}
			$menus{$menu} or $menus{$menu} = [];
			push @{$menus{$menu}}, $pkg;
		}
	}
	my @menus = sort {
		($a eq 'undef' ?  1 : 0) or
		($b eq 'undef' ? -1 : 0) or
		($a cmp $b)
	} keys %menus;

	foreach my $menu (@menus) {
		my @pkgs = sort {
			package_depends($a, $b) or
			($a-&gt;{name} cmp $b-&gt;{name})
		} @{$menus{$menu}};
		if ($menu ne 'undef') {
			$menu_dep{$menu} and print "if $menu_dep{$menu}\n";
			print "menu \"$menu\"\n";
		}
		foreach my $pkg (@pkgs) {
			my $title = $pkg-&gt;{name};
			my $c = (72 - length($pkg-&gt;{name}) - length($pkg-&gt;{title}));
			if ($c &gt; 0) {
				$title .= ("." x $c). " ". $pkg-&gt;{title};
			}
			$title = "\"$title\"";
			print "\t";
			$pkg-&gt;{menu} and print "menu";
			print "config PACKAGE_".$pkg-&gt;{name}."\n";
			$pkg-&gt;{hidden} and $title = "";
			print "\t\t".($pkg-&gt;{tristate} ? 'tristate' : 'bool')." $title\n";
			print "\t\tdefault y if DEFAULT_".$pkg-&gt;{name}."\n";
			foreach my $default (split /\s*,\s*/, $pkg-&gt;{default}) {
				print "\t\tdefault $default\n";
			}
			print mconf_depends($pkg-&gt;{name}, $pkg-&gt;{depends}, 0);
			print mconf_depends($pkg-&gt;{name}, $pkg-&gt;{mdepends}, 0);
			print "\t\thelp\n";
			print $pkg-&gt;{description};
			print "\n";

			$pkg-&gt;{config} and print $pkg-&gt;{config}."\n";
		}
		if ($menu ne 'undef') {
			print "endmenu\n";
			$menu_dep{$menu} and print "endif\n";
		}
	}
	print "endmenu\n\n";

	undef $category{$cat};
}

sub print_package_features() {
	keys %features &gt; 0 or return;
	print "menu \"Package features\"\n";
	foreach my $n (keys %features) {
		my @features = sort { $b-&gt;{priority} &lt;=&gt; $a-&gt;{priority} or $a-&gt;{title} cmp $b-&gt;{title} } @{$features{$n}};
		print &lt;&lt;EOF;
choice
	prompt "$features[0]-&gt;{target_title}"
	default FEATURE_$features[0]-&gt;{name}
EOF

		foreach my $feature (@features) {
			print &lt;&lt;EOF;
	config FEATURE_$feature-&gt;{name}
		bool "$feature-&gt;{title}"
EOF
			$feature-&gt;{description} =~ /\w/ and do {
				print "\t\thelp\n".$feature-&gt;{description}."\n";
			};
		}
		print "endchoice\n"
	}
	print "endmenu\n\n";
}

sub gen_package_config() {
	parse_package_metadata($ARGV[0]) or exit 1;
	print "menuconfig IMAGEOPT\n\tbool \"Image configuration\"\n\tdefault n\n";
	foreach my $preconfig (keys %preconfig) {
		foreach my $cfg (keys %{$preconfig{$preconfig}}) {
			my $conf = $preconfig{$preconfig}-&gt;{$cfg}-&gt;{id};
			$conf =~ tr/\.-/__/;
			print &lt;&lt;EOF
	config UCI_PRECONFIG_$conf
		string "$preconfig{$preconfig}-&gt;{$cfg}-&gt;{label}" if IMAGEOPT
		depends PACKAGE_$preconfig
		default "$preconfig{$preconfig}-&gt;{$cfg}-&gt;{default}"

EOF
		}
	}
	print "source \"package/*/image-config.in\"\n";
	if (scalar glob "package/feeds/*/*/image-config.in") {
	    print "source \"package/feeds/*/*/image-config.in\"\n";
	}
	print_package_features();
	print_package_config_category 'Base system';
	foreach my $cat (keys %category) {
		print_package_config_category $cat;
	}
}

sub get_conditional_dep($$) {
	my $condition = shift;
	my $depstr = shift;
	if ($condition) {
		if ($condition =~ /^!(.+)/) {
			return "\$(if \$(CONFIG_$1),,$depstr)";
		} else {
			return "\$(if \$(CONFIG_$condition),$depstr)";
		}
	} else {
		return $depstr;
	}
}

sub gen_package_mk() {
	my %conf;
	my %dep;
	my %done;
	my $line;

	parse_package_metadata($ARGV[0]) or exit 1;
	foreach my $name (sort {uc($a) cmp uc($b)} keys %package) {
		my $config;
		my $pkg = $package{$name};
		my @srcdeps;

		next if defined $pkg-&gt;{vdepends};

		if ($ENV{SDK}) {
			$conf{$pkg-&gt;{src}} or do {
				$config = 'm';
				$conf{$pkg-&gt;{src}} = 1;
			};
		} else {
			$config = "\$(CONFIG_PACKAGE_$name)"
		}
		if ($config) {
			$pkg-&gt;{buildonly} and $config = "";
			print "package-$config += $pkg-&gt;{subdir}$pkg-&gt;{src}\n";
			if ($pkg-&gt;{variant}) {
				if (!defined($done{$pkg-&gt;{src}})) {
					print "\$(curdir)/$pkg-&gt;{subdir}$pkg-&gt;{src}/default-variant := $pkg-&gt;{variant}\n";
				}
				print "\$(curdir)/$pkg-&gt;{subdir}$pkg-&gt;{src}/variants += \$(if $config,$pkg-&gt;{variant})\n"
			}
			$pkg-&gt;{prereq} and print "prereq-$config += $pkg-&gt;{subdir}$pkg-&gt;{src}\n";
		}

		next if $done{$pkg-&gt;{src}};
		$done{$pkg-&gt;{src}} = 1;

		if (@{$pkg-&gt;{buildtypes}} &gt; 0) {
			print "buildtypes-$pkg-&gt;{subdir}$pkg-&gt;{src} = ".join(' ', @{$pkg-&gt;{buildtypes}})."\n";
		}

		foreach my $spkg (@{$srcpackage{$pkg-&gt;{src}}}) {
			foreach my $dep (@{$spkg-&gt;{depends}}, @{$spkg-&gt;{builddepends}}) {
				$dep =~ /@/ or do {
					$dep =~ s/\+//g;
					push @srcdeps, $dep;
				};
			}
		}
		foreach my $type (@{$pkg-&gt;{buildtypes}}) {
			my @extra_deps;
			my %deplines;

			next unless $pkg-&gt;{"builddepends/$type"};
			foreach my $dep (@{$pkg-&gt;{"builddepends/$type"}}) {
				my $suffix = "";
				my $condition;

				if ($dep =~ /^(.+):(.+)/) {
					$condition = $1;
					$dep = $2;
				}
				if ($dep =~ /^(.+)(\/.+)/) {
					$dep = $1;
					$suffix = $2;
				}

				my $idx = "";
				my $pkg_dep = $package{$dep};
				if (defined($pkg_dep) &amp;&amp; defined($pkg_dep-&gt;{src})) {
					$idx = $pkg_dep-&gt;{subdir}.$pkg_dep-&gt;{src};
				} elsif (defined($srcpackage{$dep})) {
					$idx = $subdir{$dep}.$dep;
				} else {
					next;
				}
				my $depstr = "\$(curdir)/$idx$suffix/compile";
				my $depline = get_conditional_dep($condition, $depstr);
				if ($depline) {
					$deplines{$depline}++;
				}
			}
			my $depline = join(" ", sort keys %deplines);
			if ($depline) {
				$line .= "\$(curdir)/".$pkg-&gt;{subdir}."$pkg-&gt;{src}/$type/compile += $depline\n";
			}
		}

		my $hasdeps = 0;
		my %deplines;
		foreach my $deps (@srcdeps) {
			my $idx;
			my $condition;
			my $prefix = "";
			my $suffix = "";

			if ($deps =~ /^(.+):(.+)/) {
				$condition = $1;
				$deps = $2;
			}
			if ($deps =~ /^(.+)(\/.+)/) {
				$deps = $1;
				$suffix = $2;
			}

			my $pkg_dep = $package{$deps};
			my @deps;

			if ($pkg_dep-&gt;{vdepends}) {
				@deps = @{$pkg_dep-&gt;{vdepends}};
			} else {
				@deps = ($deps);
			}

			foreach my $dep (@deps) {
				$pkg_dep = $package{$deps};
				if (defined $pkg_dep-&gt;{src}) {
					($pkg-&gt;{src} ne $pkg_dep-&gt;{src}.$suffix) and $idx = $pkg_dep-&gt;{subdir}.$pkg_dep-&gt;{src};
				} elsif (defined($srcpackage{$dep})) {
					$idx = $subdir{$dep}.$dep;
				}
				$idx .= $suffix;
				undef $idx if $idx =~ /^(kernel)|(base-files)$/;
				if ($idx) {
					my $depline;
					next if $pkg-&gt;{src} eq $pkg_dep-&gt;{src}.$suffix;
					next if $dep{$condition.":".$pkg-&gt;{src}."-&gt;".$idx};
					next if $dep{$pkg-&gt;{src}."-&gt;($dep)".$idx} and $pkg_dep-&gt;{vdepends};
					my $depstr;

					if ($pkg_dep-&gt;{vdepends}) {
						$depstr = "\$(if \$(CONFIG_PACKAGE_$dep),\$(curdir)/$idx/compile)";
						$dep{$pkg-&gt;{src}."-&gt;($dep)".$idx} = 1;
					} else {
						$depstr = "\$(curdir)/$idx/compile";
						$dep{$pkg-&gt;{src}."-&gt;".$idx} = 1;
					}
					$depline = get_conditional_dep($condition, $depstr);
					if ($depline) {
						$deplines{$depline}++;
					}
				}
			}
		}
		my $depline = join(" ", sort keys %deplines);
		if ($depline) {
			$line .= "\$(curdir)/".$pkg-&gt;{subdir}."$pkg-&gt;{src}/compile += $depline\n";
		}
	}

	if ($line ne "") {
		print "\n$line";
	}
	foreach my $preconfig (keys %preconfig) {
		my $cmds;
		foreach my $cfg (keys %{$preconfig{$preconfig}}) {
			my $conf = $preconfig{$preconfig}-&gt;{$cfg}-&gt;{id};
			$conf =~ tr/\.-/__/;
			$cmds .= "\techo \"uci set '$preconfig{$preconfig}-&gt;{$cfg}-&gt;{id}=\$(subst \",,\$(CONFIG_UCI_PRECONFIG_$conf))'\"; \\\n";
		}
		next unless $cmds;
		print &lt;&lt;EOF

ifndef DUMP_TARGET_DB
\$(TARGET_DIR)/etc/uci-defaults/$preconfig: FORCE
	( \\
$cmds \\
	) &gt; \$@
	
ifneq (\$(IMAGEOPT)\$(CONFIG_IMAGEOPT),)
  package/preconfig: \$(TARGET_DIR)/etc/uci-defaults/$preconfig
endif
endif

EOF
	}
}

sub gen_package_source() {
	parse_package_metadata($ARGV[0]) or exit 1;
	foreach my $name (sort {uc($a) cmp uc($b)} keys %package) {
		my $pkg = $package{$name};
		if ($pkg-&gt;{name} &amp;&amp; $pkg-&gt;{source}) {
			print "$pkg-&gt;{name}: ";
			print "$pkg-&gt;{source}\n";
		}
	}
}

sub parse_command() {
	my $cmd = shift @ARGV;
	for ($cmd) {
		/^target_config$/ and return gen_target_config();
		/^package_mk$/ and return gen_package_mk();
		/^package_config$/ and return gen_package_config();
		/^kconfig/ and return gen_kconfig_overrides();
		/^package_source$/ and return gen_package_source();
	}
	print &lt;&lt;EOF
Available Commands:
	$0 target_config [file] 	Target metadata in Kconfig format
	$0 package_mk [file]		Package metadata in makefile format
	$0 package_config [file] 	Package metadata in Kconfig format
	$0 kconfig [file] [config]	Kernel config overrides
	$0 package_source [file] 	Package source file information

EOF
}

parse_command();
</pre></body></html>