tools/missing-macros/src/m4/uintmax_t.m4

   1 # uintmax_t.m4 serial 12
   2 dnl Copyright (C) 1997-2004, 2007-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Paul Eggert.
   8
   9 AC_PREREQ([2.13])
  10
  11 # Define uintmax_t to 'unsigned long' or 'unsigned long long'
  12 # if it is not already defined in <stdint.h> or <inttypes.h>.
  13
  14 AC_DEFUN([gl_AC_TYPE_UINTMAX_T],
  15 [
  16   AC_REQUIRE([gl_AC_HEADER_INTTYPES_H])
  17   AC_REQUIRE([gl_AC_HEADER_STDINT_H])
  18   if test $gl_cv_header_inttypes_h = no && test $gl_cv_header_stdint_h = no; then
  19     AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
  20     test $ac_cv_type_unsigned_long_long_int = yes \
  21       && ac_type='unsigned long long' \
  22       || ac_type='unsigned long'
  23     AC_DEFINE_UNQUOTED([uintmax_t], [$ac_type],
  24       [Define to unsigned long or unsigned long long
  25        if <stdint.h> and <inttypes.h> don't define.])
  26   else
  27     AC_DEFINE([HAVE_UINTMAX_T], [1],
  28       [Define if you have the 'uintmax_t' type in <stdint.h> or <inttypes.h>.])
  29   fi
  30 ])